home *** CD-ROM | disk | FTP | other *** search
/ Cream of the Crop 25 / Cream of the Crop 25.iso / os2 / gnuwget.zip / wget-1.4.3 / aclocal.m4 next >
Text File  |  1997-01-18  |  2KB  |  89 lines
  1. AC_DEFUN(AM_C_PROTOTYPES,
  2. [AC_REQUIRE([AM_PROG_CC_STDC])
  3. AC_BEFORE([$0], [AC_C_INLINE])
  4. AC_MSG_CHECKING([for function prototypes])
  5. if test "$am_cv_prog_cc_stdc" != no; then
  6.   AC_MSG_RESULT(yes)
  7.   AC_DEFINE(PROTOTYPES)
  8.   U= ANSI2KNR=
  9. else
  10.   AC_MSG_RESULT(no)
  11.   U=_ ANSI2KNR=./ansi2knr
  12.   # Ensure some checks needed by ansi2knr itself.
  13.   AC_HEADER_STDC
  14.   AC_CHECK_HEADERS(string.h)
  15. fi
  16. AC_SUBST(U)dnl
  17. AC_SUBST(ANSI2KNR)dnl
  18. ])
  19.  
  20.  
  21. # serial 1
  22.  
  23. # @defmac AC_PROG_CC_STDC
  24. # @maindex PROG_CC_STDC
  25. # @ovindex CC
  26. # If the C compiler in not in ANSI C mode by default, try to add an option
  27. # to output variable @code{CC} to make it so.  This macro tries various
  28. # options that select ANSI C on some system or another.  It considers the
  29. # compiler to be in ANSI C mode if it defines @code{__STDC__} to 1 and
  30. # handles function prototypes correctly.
  31. #
  32. # If you use this macro, you should check after calling it whether the C
  33. # compiler has been set to accept ANSI C; if not, the shell variable
  34. # @code{am_cv_prog_cc_stdc} is set to @samp{no}.  If you wrote your source
  35. # code in ANSI C, you can make an un-ANSIfied copy of it by using the
  36. # program @code{ansi2knr}, which comes with Ghostscript.
  37. # @end defmac
  38.  
  39. AC_DEFUN(AM_PROG_CC_STDC,
  40. [AC_REQUIRE([AC_PROG_CC])
  41. AC_MSG_CHECKING(for ${CC-cc} option to accept ANSI C)
  42. AC_CACHE_VAL(am_cv_prog_cc_stdc,
  43. [am_cv_prog_cc_stdc=no
  44. ac_save_CC="$CC"
  45. # Don't try gcc -ansi; that turns off useful extensions and
  46. # breaks some systems' header files.
  47. # AIX            -qlanglvl=ansi
  48. # Ultrix and OSF/1    -std1
  49. # HP-UX            -Aa -D_HPUX_SOURCE
  50. # SVR4            -Xc -D__EXTENSIONS__
  51. for ac_arg in "" -qlanglvl=ansi -std1 "-Aa -D_HPUX_SOURCE" "-Xc -D__EXTENSIONS__"
  52. do
  53.   CC="$ac_save_CC $ac_arg"
  54.   AC_TRY_COMPILE(
  55. [#if !defined(__STDC__) || __STDC__ != 1
  56. choke me
  57. #endif
  58. /* DYNIX/ptx V4.1.3 can't compile sys/stat.h with -Xc -D__EXTENSIONS__. */
  59. #ifdef _SEQUENT_
  60. # include <sys/types.h>
  61. # include <sys/stat.h>
  62. #endif
  63. ], [
  64. int test (int i, double x);
  65. struct s1 {int (*f) (int a);};
  66. struct s2 {int (*f) (double a);};],
  67. [am_cv_prog_cc_stdc="$ac_arg"; break])
  68. done
  69. CC="$ac_save_CC"
  70. ])
  71. AC_MSG_RESULT($am_cv_prog_cc_stdc)
  72. case "x$am_cv_prog_cc_stdc" in
  73.   x|xno) ;;
  74.   *) CC="$CC $am_cv_prog_cc_stdc" ;;
  75. esac
  76. ])
  77.  
  78. AC_DEFUN(AM_STRUCT_UTIMBUF,
  79. [AC_MSG_CHECKING(for struct utimbuf)
  80. if test x"$ac_cv_header_utime_h" = xyes; then
  81.   AC_EGREP_CPP([struct +utimbuf],
  82.     [#include <utime.h>],
  83.     [AC_DEFINE(HAVE_STRUCT_UTIMBUF)
  84.       AC_MSG_RESULT(yes)],
  85.     AC_MSG_RESULT(no))
  86. else
  87.   AC_MSG_RESULT(no)
  88. fi])
  89.